attachment:addCopyright.pl of License_clean-up_RFC

Attachment 'addCopyright.pl'

#!/usr/bin/perl
#
# A program that adds a generic copyright and warranty statement
# to a file.
#

use File::Basename;
use strict;
use Getopt::Long;

use vars qw($silent);

main();

sub main
{
	my $author = "";
	my $headerFile = "";
	my $force = 0;
	my $extract = 0;
	$silent = 0;
	my $result = GetOptions( "author|a=s" => \$author,
	                         "header|h=s" => \$headerFile,
	                         "force|f" => \$force,
	                         "extract|x" => \$extract,
                                 "silent|s" => \$silent);
	
	die "USAGE: addCopyright.pl -a <author> [-h <header file>] [--extract] [--force] [--silent] <file> <file2> ... \n\nHeader files available in ~/bin/copyrights.\n"
		if ( $author eq "" );

	my $header = "";
	if ( $headerFile ne "" ) 
	{
		open HEAD, "$headerFile" or die "Couldn't open header: '$headerFile'\n";
		while (<HEAD>) { $header .= $_ ; }
		close HEAD;
	}

	foreach (@ARGV) { addCopy( $_, $author, $header, $force, $extract ); }
}

sub addCopy
{
	my $filename = shift;
	my $file = basename($filename); 
	my $author = shift;
	my $header = shift;
	my $force = shift;
	my $extract = shift;

	my $year = (localtime)[5] + 1900;

	my $startComment = "";
	my $c = "";
	my $endComment = "";

	my $extractBegin = '';
	my $extractEnd = '';
	my $extractLine = '';

	my $valid = 0;

	if ( $filename =~ /.+\.html$/i ||  
   		  $filename =~ /.+\.htm$/i  || 
   		  $filename =~ /.+\.xml$/i  || 
   		  $filename =~ /.+\.dtd$/i  
		 )
	{
		$startComment = "<!--";
		$c            = "  - ";
		$endComment   = "  -->";
		$valid = 1;

		$extractBegin = '\<\!--';
		$extractEnd   = '--\>';
	}
	elsif ( $filename =~ /.+\.pl$/i ||  
		     $filename =~ /.+\.pm$/i || 
		     $filename =~ /.+\.sh$/i || 
		     $filename =~ /.+\.ksh$/i || 
		     $filename =~ /.+\.bash$/i || 
		     $filename =~ /.+\.csh$/i || 
		     $filename =~ /.+\.tcsh$/i || 
		     $filename =~ /.+\.py$/i || 
		     $filename =~ /^makefile$/i 
		 ) 
	{
		$startComment = "#=============================================================================";
		$c            = "# ";
		$endComment   = "#============================================================================";
		$valid = 1;

		$extractLine = '\#';
	}
	elsif ( $filename =~ /.+\.c$/i ||  
  		     $filename =~ /.+\.h$/i ||
		     $filename =~ /.+\.cpp$/i ||
		     $filename =~ /.+\.cxx$/i ||
		     $filename =~ /.+\.cc$/i ||
		     $filename =~ /.+\.css$/i
		 ) 
	{
		$startComment = "/*****************************************************************************\\ ";
		$c            = " * ";
		$endComment   = "\\*****************************************************************************/";
		$valid = 1;

		$extractBegin = '\/\*';
		$extractEnd   = '\*\/';
		$extractLine  = '\/\/';
	}
	elsif ( $filename =~ /.+\.java$/i )
	{
#		$startComment = "//============================================================================";
#		$c            = "// ";
#		$endComment   = "//============================================================================";
		$startComment = "/*";
		$c            = " ";
		$endComment   = "*/";
		$valid = 1;

		$extractBegin = '\/\*';
		$extractEnd   = '\*\/';
		$extractLine  = '\/\/';
	}
	elsif( $filename =~ /.+\.1$/ )
	{
		$startComment = ".\\" . "\"";
		$c            = ".\\" . "\"";
		$endComment   = ".\\" . "\"";
		$valid = 1;

		$extractLine  = '\.\\\\' . '\"';
	}
	elsif( $filename =~ /.+\.sql$/i )
	{
		$startComment = "------------------------------------------------------------------------------- ";
		$c            = "--";
		$endComment   = "------------------------------------------------------------------------------- ";
		$valid = 1;

		$extractLine  = '\.\.';
	}
	else
	{
		printMessage( "File suffix for: \'$filename\' doesn't match " . 
		              "any known patterns!\nNot adding copyright!\n\n" );
		return;
	}

	# if the header isn't set, use this basic default
	if ( $header eq "" ) 
	{
		$header =
"
$startComment
$c
$c file:  $file
$c
$c Copyright (c) $year, $author
$c All rights reverved.
$c
$endComment 

";
	}
	else 
	{
		$header = eval "$header";
	}


	# actually write add the header to the file 
	if ( $valid )
	{
		my @f = ();
		open FILE, "$filename" or die "couldn't open file \'$filename\'\n$!";
		while (<FILE>) { push @f, $_; }
		close FILE;

		# First, extract any existing copyright if desired.
		if ( $extract ) 
		{
			@f = extractBlockCopyright($extractBegin,$extractEnd,\@f);
			@f = extractLineCopyright($extractLine,\@f);
		}

		# Check for an existing copyright. 
		if ( !$force )
		{
			checkExisting($filename, \@f);
		}

		printMessage( "Adding copyright to file: \'$filename\'\n" ); 

		# check to see if first line of file is a shebang (e.g. #!/bin/bash)
		my $shebang = 0;
		if ( $f[0] =~ /^\#\!\/.+/ ) { $shebang = 1; }

		# ok, add the copyright
		open FILE, ">$filename" or die "couldn't open file to write \'$filename\'\n$!";

		if ( $shebang ) { print FILE shift @f; }
		print FILE $header;
		foreach my $x (@f) { print FILE $x; }

		close FILE;
	}
}

sub printMessage
{
	my $message = shift;

	unless( $silent ) { print $message; }
}

sub checkExisting
{
	my $filename = shift;
	my $f = shift;
	foreach (@$f) 
	{ 
		if ( $_ =~ /copyright/i || $_ =~ /license/i )
		{
			printMessage( "It appears that file: \'$filename\' may ".
			          "already have a copyright notice.\n".
				  "NOT adding a copyright.\n".
				  "If this is a mistake, use the --force option\n\n" );
			exit 1;
		}
	}
}


sub extractBlockCopyright {
	
	my $beginStyle = shift;
	my $endStyle = shift;
	my $lines = shift;

	if ( $beginStyle eq "" || $endStyle eq "" ) { return @$lines; }

	my @goodlines = ();
	my @badlines = ();
	my $withinComment = 0;
	my $foundCopyright = 0;

	foreach (@$lines) {
	
		if ( !$foundCopyright && $_ =~ /$beginStyle.*$/ ) {
			$withinComment = 1;
			push @badlines, $_;
		} elsif ( $foundCopyright && $withinComment && 
		          $_ =~ /.*($endStyle)/ ) {
			$withinComment = 0;
			push @badlines, $_;
		} elsif ( $withinComment ) {
			push @badlines, $_;
		} else {
			push @goodlines, $_;
		}

		if ( $withinComment && 
		     ($_ =~ /copyright/i || $_ =~ /license/i )) {
			$foundCopyright = 1;
		}
	}

	if ( $foundCopyright && $#goodlines >=0 && $#badlines >= 0 ) {
		printMessage( "Found block copyright and extracted it.\n" );
		return @goodlines;	
	} else {
		return @$lines;	
	}
}


sub extractLineCopyright {

	my $style = shift;
	my $lines = shift;

	if ( $style eq "" ) { return @$lines; }

	my @goodlines = ();
	my @badlines = ();

	my $foundCopyright = 0;
	my $skip = 0;

	foreach (@$lines) {

		if ( !$skip && $_ =~ /^\s*($style.*)$/ ) {
			push @badlines, $_;
		} else {
			push @goodlines, $_;
			if ( $#badlines >= 0 ) { $skip = 1; }
		}

		if ($_ =~ /copyright/i || $_ =~ /license/i ) {
			$foundCopyright = 1;
		}
	
	}

	if ( $foundCopyright ) {
		printMessage( "Found line copyright and extracted it.\n");
		return @goodlines;
	} else {
		return @$lines;
	}
}
Attached Files

To refer to attachments on a page, use attachment:filename, as shown below in the list of files. Do NOT use the URL of the [get] link, since this is subject to change and can break easily.
[get | view] (2011-10-20 20:44:22, 6.8 KB) [[attachment:addCopyright.pl]]
[get | view] (2011-10-20 20:44:22, 1.7 KB) [[attachment:header.cytoscape]]
You are not allowed to attach a file to this page.